Silme İşlemi

[Mdemir63]

Selamlar

Arkadaşlar Ekteki dosyada Combobox dan seçtiğim Firmayı sayfada bularak firma isminin olduğu tüm satırları sildirmek istiyorum. Ayrıca Combobox içinden de silmesi gerekiyor. Daha sonrada yeniden sıra numarası vermesini yaptırmak istiyorum .
Nasıl yapabilirim?


Saygılar

 

[Ömer]

Merhaba,

Deneyiniz.

Private Sub CommandButton1_Click()

    Dim c As Range, k As Range, Adr As String, son As Long
   
    Application.ScreenUpdating = False
   
    Set c = [B:B].Find([Q1], , xlValues, xlWhole)
    If Not c Is Nothing Then
        Adr = c.Address
        Do
            If k Is Nothing Then
                Set k = Cells(c.Row, "A").Resize(1, 5)
            Else
                Set k = Union(k, Cells(c.Row, "A").Resize(1, 5))
            End If
            Set c = [B:B].FindNext(c)
        Loop While Not c Is Nothing And c.Address <> Adr
    End If   
    If Not k Is Nothing Then k.Delete Shift:=xlUp
   
    Set c = [S:S].Find([Q1], , xlValues, xlWhole)
    If Not c Is Nothing Then
        c.Delete Shift:=xlUp
    End If
   
    Range("A2:A" & Rows.Count) = ""
    son = Cells(Rows.Count, "B").End(xlUp).Row - 1
    If son > 0 Then
        Range("A2") = 1
        Range("A2").Resize(son, 1).DataSeries Type:=xlLinear, Step:=1
    End If
   
    Application.ScreenUpdating = True
   
End Sub

 

[Mdemir63]

Ömer Hocam
Elinize sağlık çok teşekkür ederim.

Saygılar