• DİKKAT

    DOSYA İndirmek/Yüklemek için ÜCRETLİ ALTIN ÜYELİK Gereklidir!
    Altın Üyelik Hakkında Bilgi

Son Kelime Büyük diğerleri küçük yazsın

H

Hacı Bayram ÖZKAN

Katılım
24 Şubat 2009
Mesajlar
1,077
Excel Vers. ve Dili
2016
Merhaba arkadaşlar; B1 hücresinde HACI BAYRAM ÖZKAN diye bir ve buna benzer isimler, K24 hücresine sağdan son kelime BÜYÜK diğerleri küçük yazdırmak için bir formül istiyorum. Yani sonuçta "Hacı Bayram ÖZKAN" yazacak herkese teşekkür ederim.
 
=YAZIM.DÜZENİ(SOLDAN(B1;UZUNLUK(B1)-UZUNLUK(KIRP(SAĞDAN(YERİNEKOY(B1;" ";YİNELE(" ";100));100)))))&BÜYÜKHARF(KIRP(SAĞDAN(YERİNEKOY(B1;" ";YİNELE(" ";100));100)))
 
Sayın abim bir yerde galiba eksiklik var olmuyor, baktım bulamadım size zahmet bir bakarsanız. Teşekkürler.
 
Aşağıdaki formülü deneyiniz. Yalnız son kelime B1 hücresinde birden fazla varsa sonuç hatalı olur. Örneğin ali veli develi için Ali Veli DEVELİ sonucunu verirken ali veli veli için Ali VELİ sonucunu verir:

=KIRP(YAZIM.DÜZENİ(YERİNEKOY(B1;PARÇAAL(B1;MBUL("@";YERİNEKOY(B1;" ";"@";UZUNLUK(B1)-UZUNLUK(YERİNEKOY(B1;" ";"")));1)+1;UZUNLUK(B1));""))&BÜYÜKHARF(PARÇAAL(B1;MBUL("@";YERİNEKOY(B1;" ";"@";UZUNLUK(B1)-UZUNLUK(YERİNEKOY(B1;" ";"")));1)+1;UZUNLUK(B1))))

Formülün orijinalini forumdan almıştım.
 
tarzanhaci' Alıntı:
Merhaba arkadaşlar; B1 hücresinde HACI BAYRAM ÖZKAN diye bir ve buna benzer isimler, K24 hücresine sağdan son kelime BÜYÜK diğerleri küçük yazdırmak için bir formül istiyorum. Yani sonuçta "Hacı Bayram ÖZKAN" yazacak herkese teşekkür ederim.
Genişletmek için tıkla ...

Merhabalar. Aşağıdaki şekilde denermisiniz lütfen.
F4 yazan yere kelimenin bulunduğu hücreyi yazabilirsiniz.

=BÜYÜKHARF(SAĞDAN(F4;((BUL(" ";F4;1)))))
 
YUSUF BEY; Teşekkürler oldu eline sağlık, Sayın Thalees sizinki sadece soyismi keserek aldı, sorumu galiba yanlış anlamışsınız? Yusuf beyin formülü tam uydu her ikinizede teşekkür ederim.
 
Alternatif;

C++: 
=EĞER(UZUNLUK(B1)-UZUNLUK(YERİNEKOY(B1;" ";""))=0;YAZIM.DÜZENİ(B1);YAZIM.DÜZENİ(KIRP(SOLDAN(B1;BUL("#";YERİNEKOY(B1;" ";"#";UZUNLUK(B1)-UZUNLUK(YERİNEKOY(B1;" ";"")))))))&PARÇAAL(B1;BUL("#";YERİNEKOY(B1;" ";"#";UZUNLUK(B1)-UZUNLUK(YERİNEKOY(B1;" ";""))));255))
 
Bana da forumdaki @çıtır isimli üye aynı konuda yardımcı olmuştu.
B1'e kaç sözcük yazarsanız yazın ilk iletide beklediğiniz sonucu yazıyor. B1 boşsa hata değeri göstermiyor.
Alternatif olarak paylaşayım istedim.
=EĞERHATA(KIRP(YAZIM.DÜZENİ(SOLDAN(YERİNEKOY(KIRP(B1)&" ";" ";YİNELE(" ";255);UZUNLUK(KIRP(B1))-UZUNLUK(YERİNEKOY(KIRP(B1);" ";"")));255)))&" "&BÜYÜKHARF(PARÇAAL(KIRP(B1);1+BUL("*";YERİNEKOY(KIRP(B1);" ";"*";UZUNLUK(KIRP(B1))-UZUNLUK(YERİNEKOY(KIRP(B1);" ";""))));255));"")
 
Herkese teşekkür ederim, sorum çözüldü dua ile kalın, eksik olmayın iyi ki varsınız?
 
Cevap yazmak için giriş yap yada kayıt ol.
Geri
Üst