ŞUBAT AYI 28 VEYA 29

[iplikci_80]

Arkadaşlar D1 hücresine nasıl bir formül yazmalıyım ki B2 hücresi "ŞUBAT" ise ve B4 hücresi 27 den büyük ise 30 değilse B4 hücresine eşit olsun.

 

[Orion1]

Deneyiniz.
=EĞER(VE(B2="ŞUBAT";B4>27;B4<>30);B4;"")

 

[Ömer BARAN]

Yanlış anlamadıysam;

=EĞER(VE(B2="ŞUBAT";B4>27);30;B4)

 

[iplikci_80]

Sayın Orion 1 ve sayın Ömer BARAN ilginize teşekkür ederim.

 

[iplikci_80]

Ömer Bey merhabalar yukarıdaki formülü D1 hücresine B2 hücresi "ŞUBAT" ise ve B4 hücresi 28 yada 29 ise 30 değilse B4 hücresine eşit olsun şeklinde nasıl düzenleme hususunda yardımlarınızı rica ediyorum.

 

[Ömer BARAN]

Verdiğim formül zaten istediğiniz işlemi yapıyor.
Sanıyorum kastınız; 28 ya da 29 değil, "ayın son günü".
.

 

[iplikci_80]

Bunu puantajda kullanıyorum ve EK'teki örnek çalışmanın AV7 hücresinin 28 yada 29 olmasını kast ediyorum.

 

[Ömer BARAN]

Aşağıdaki formül işinizi görebilir.

=EĞER(GÜN(MAK($F$5:$AJ$5))=AV7;30;AV7)

 

[iplikci_80]

AV7 28 ise 30 oluyor ama AV7 29 ise 29 oluyor yine 30 olması gerekir.

 

[İdris SERDAR]

.

Sorunuz pek anlaşılmıyor.

Eğer istediğiniz, her ay ne kadar çekiyorsa tarihler o kadar olsun ise;

Dosya ekte.

.

 

[Ömer BARAN]

Öncelikle aşağıdaki formülü F5 hücresine uygulayıp sağa doğru kopyalayın, böylece takviminiz seçilen ay ve yıla göre belirlenmiş olacaktır.
Hafta tatili tespitini de buna göre yapmaya bakın.

=EĞERHATA(SAYIYAÇEVİR(SÜTUN(A$1)&" "&$F$2&" "&$V$2);"")

Puantaj döneminin belirlendiği üstteki takvim kısmını ve EĞERSAY işlevinde X'lerin sayılacağı alanın tespiti kısmını gözden geçirmek gerekir.
Sayım alanını ilgili ayın günlerine ait kısımla sınırlamak için (yani 2019 Şubat için soldan 28 sütun, Mart 2019 için 31 sütun gibi)
aşağıdaki formülü kullanabilirsiniz.
Dikkat edilecek husus; örneğin Şubat 2019 ayı için AH sütununda X varsa da sayıma dahil edilmeyeceğidir (zaten edilmemeli bence).

=EĞERSAY(KAYDIR($E8;0;1;;GÜN(SERİAY(SAYIYAÇEVİR("1 "&$F$2&" "&$V$2);0)));"X")

 

[iplikci_80]

İdris bey merhabalar ilginize teşekkür ederim. Sorum şu cevap 7 deki çalışmada AW7 nasıl bir formül yazalım ki ŞUBAT ayında AV7 28 veya 29 ise AW7 30 olsun.

 

[iplikci_80]

Ömer Bey ikinci formül nereye konacak.

 

[Ömer BARAN]

Yanlış anlamıyorsam;
-- Birleştirilmiş AO7 hücresine birinci formülü,
-- Birleştirilmiş AL7 hücresine ikinci formülü,
-- Birleştirilmiş AW7 hücresine üçüncü formülü
uygulayınca istediğiniz sonuç elde edilir.
Önceki mesajımda da belirttiğim gibi ilgili ayın son gününden sonraki hücrelere yazılan X'ler vs sayıma dahil edilmez.

=TOPLA.ÇARPIM((KAYDIR($E$6;0;1;;GÜN(SERİAY(SAYIYAÇEVİR("1 "&$F$2&" "&$V$2);0))))*(KAYDIR($E8;0;1;;GÜN(SERİAY(SAYIYAÇEVİR("1 "&$F$2&" "&$V$2);0)))="X"))
=EĞERSAY(KAYDIR($E8;0;1;;GÜN(SERİAY(SAYIYAÇEVİR("1 "&$F$2&" "&$V$2);0)));"X")-$AO7
=EĞER(GÜN(SERİAY(SAYIYAÇEVİR("1 "&$F$2&" "&$V$2);0))=AV7;30;AV7)

 

[iplikci_80]

Ömer Bey ilginize teşekkür ederim.

 

[Ömer BARAN]

Estağfurullah, kolay gelsin.

Son bir hatırlatma: AH:AJ sütun aralığına koşullu biçimlendirme uygulamanızda yarar olacağını düşünüyorum.
Amaç; 5'inci satırdaki tarih hücresi boş ve bu boş olan değerin sütunundaki alt kısım hücrelerde değer varsa bunların silinmesi daha şık duracağından,
silme uyarısı gibi işlev görür. Renk olarak KIRMIZI gibi dikkat çekici bir renk uygulayın.
Koşullu biçimlendirme için AH7:AJ46 aralığını seçip koşullu biçimlendirmeye aşağıdaki formülü uygulayın.

=VE(AH$5="";AH7<>"")

 

[iplikci_80]

Hatırlatma için teşekkür ederim. Fakat yapma çalıştım ama fark eden bir şey olmadı.

 

[Ömer BARAN]

Koşullu biçimlendirme dahil, işlemlerin uygulandığı belge ekte.
6'ncı satırı, ilk belgenizdeki gibi gizleyebilirsiniz.

 

[iplikci_80]

Çok teşekkür ederim.

 

[ekimurat]

sitedeki herşey altın üyelik mi oldu örnek dosyalara bile bakamıyoruz artık