Tekrarlanan Değerlerin ilkine belirteceğim sütuna 1 yazma

[eceLprensi]

Merhaba

Yinelenen değerlerin 1.sine 1 yazıp diğer tekrarlananlara boş bırakabileceğim bir formül yada makro varmıdır?

Yardımlarınız için Teşekkürler.

 

[Ömer]

Merhaba,

Verileriniz A2 den başlandığı düşüldü:

B2:

=EĞER(EĞERSAY($A$2:A2;A2)=1;1;"")

.

 

[eceLprensi]

Teşekkürler.

600000 satırda çok kastı. 1 saat sürdü formül

işimi gördü ama

Emeklerinize sağlık.

 

[Korhan Ayhan]

Alternatif;

Makro ile daha hızlı sonuç alabilirsiniz.

Option Explicit

Sub Tekrarlananlarin_Ilkine_Bir_Yaz()
    Dim Son As Long, Veri As Variant, X As Long, Say As Long, Zaman As Double
    
    Zaman = Timer
    
    Son = Cells(Rows.Count, 1).End(3).Row
    If Son = 2 Then Son = 3
    
    Veri = Range("A2:A" & Son)
    
    ReDim Liste(1 To UBound(Veri), 1 To 1)
    
    With CreateObject("Scripting.Dictionary")
        For X = LBound(Veri) To UBound(Veri)
            Say = Say + 1
            If Not .Exists(Veri(X, 1)) Then
                .Add Veri(X, 1), Say
                Liste(Say, 1) = 1
            End If
        Next
    End With
    
    Range("B2").Resize(Say) = Liste
    
    MsgBox "İşleminiz tamamlanmıştır." & Chr(10) & Chr(10) & _
           "İşlem süresi ; " & Format(Timer - Zaman, "0.00") & " Saniye", vbInformation
End Sub

 

[eceLprensi]

Tamda aradığım şey buydu.
Emeklerinize sağlık.