Tekrarlayan isimler ve tarihler için koşullu biçimlendirme

[emm01]

Değerli arkadaşlar zor bir konuda yardıma ihtiyacım var. şimdi a sütununda arkadaşlarımızın ismi olsun b sütununda da bu arkadaşlarımızla hangi tarihlerde görüştüğümüz tgün ay yıl tarih formatında yazıyor olsun. a sütununda farklı isimler olduğu gibi tekrarlı görüştüğümüz için bir arkadaşımızın ismi birden çok kere yazılmış ve karşısında da hangi tarihte görüştüğümüz yazıyor olabilir. şimdi biz 3 gün veya daha kısa süreli görüştüğümüz arkadaşlarımızı vurgulamak istiyoruz. bunu nasıl sağlayabiliriz.

örnek olarak ben ahmet mehmet cevdet ve can ile görüştüm. bunlarla birden fazla kere görüştüm diyelim. bu görüşmelerim içerisinde aynı kişiyle 3 gün veya daha kısa sürede görüşmüşsem koşullu biçimlendirme bana bunu vurgulasın istiyorum.

yardımlarınız için teşekkür ederim

 

[HücrelereFısıldayanAdam]

A ve B deki veriyi seçin, koşullu biçimlendirme ye girin,
"yeni kuralı" seçin, en altta ".... için formül kullan" yazıyor onu seçin,
=B1>=BUGÜN()-3 formülünü girin, en alttan istediğiniz biçimlendirme ayarlarını yapın.

 

[emm01]

Yalnız burada şöyle bir detay var mesela Ahmet isimli arkadaşımla 3 farklı görüşme oldu diyelim ve Ahmet 3 kere satırda yer aldı ve karşısında da görüşme tarihlerimiz yer aldı. Burada örneğin Ahmet ile 1 Ocak, 3 Ocak ve 17 ocakta görüşmüş olalım. Benim excelden isteğim 1 ve 3 Ocak satırlarındaki Ahmet ismini boyaması. Ben bugün tarihli mukayese değil o ismin karşısına girilen tarihli bir mukayese kastetmiştim. Yapay zeka şöyle bir formül önerdi lakin Türkçeye de çevirdiğim halde çalıştıramadım.

=AND($A1=A1,ABS($B1-B1)<3)

verisetimde a sütunu metin b sütunu tarih formatında

@fdemirci7

 

[52779]

Ahmet ile 1 Ocak, 3 Ocak ve 17 ocakta görüşmüş olalım. Benim excelden isteğim 1 ve 3 Ocak satırlarındaki Ahmet ismini boyaması.

Aynı isimlerin Maxi Tarih hariç diğerlerinin renklendirilmesi olarak anlıyorum...

Verileriniz
A2 : B500 aralığında olsun.
(A1 ve B1 de ise İsim ve Tarih Başlıkları olduğunu varsayıyorum)

Koşullu Biçimlendirme için
Örneğin A2 : B2000 aralığını seçin (ya da sonradan Kuralları Yönet ile biçimlendirme aralığını düzenleyin)
Formül olarak da
Excel 2010 ve üzeri versiyonlar için

=VE($B2<>"";$B2<ÇOKEĞERMAK($B$2:$B$2000;$A$2:$A$2000;$A2))

ya da Excel 365 kullanıcısı olduğunuzdan Excel2021 ve üzeri versiyonlar için

=VE($B2<>"";$B2<MAK(FİLTRE($B$2:$B$2000;$A$2:$A$2000=$A2)))

Örnek dokumanı inceleyebilirsiniz...

CF_BenzMak.xlsx dosyasını indir - download

CF_BenzMak.xlsx dosyasını indir, download. Dosya.tc .Dosya Upload. Dosya Paylaş. Dosya Yükle

s6.dosya.tc

 

[emm01]

emekleriniz için çok teşekkür ederim burada maksimum tarihin dışarıda kalması değil de birbirine 3 veya daha az gün olacak şekilde yakın olan aynı isme dair satırların boyanması diyebiliriz örneğin aşağıda 1 ve 4 numaralı satırdaki alileri boyamalı ama 9 numaralı aliyi almamalı çünkü onun tarihi 3 günden fazla yine 15 ve 18. merti boyamalı ama 6. merti almamalı çünkü birbirine 3 gün ve. daha yakın tarihli olan mertlerden biri değil o. yine 10 ve 12. köksalı boyamalı ama 5. köksalı dahil etmemeli @52779

1​	ali	1.01.2024
2​	mehmet	2.01.2024
3​	ahmet	3.01.2024
4​	ali	4.01.2024
5​	köksal	5.01.2024
6​	mert	6.01.2024
7​	cansu	7.01.2024
8​	elif	8.01.2024
9​	ali	9.01.2024
10​	köksal	10.01.2024
11​	cemil	11.01.2024
12​	köksal	12.01.2024
13​	zuhal	13.01.2024
14​	kerem	14.01.2024
15​	mert	15.01.2024
16​	kerem	16.01.2024
17​	ali	17.01.2024
18​	mert	18.01.2024

 

[52779]

Bu durumda,
Şöyle deneyiniz....

Tablonuza göre verilerinizin A1 den başlayarak A ve B kolonlarında olduğunu varsayarak

Koşullu Biçimlendirme
Alan : A1 : B2000 olsun.
Formülü ise

=VE($B1<>"";$A1<>"";TOPLA.ÇARPIM(($A$1:$A$2000=$A1)*(MUTLAK($B1-$B$1:$B$2000)<4))>1)

Ekleme
Excel2021 ve üzeri versiyonlarda şu formül de kullanılabilir.

=VE($A1<>"";$B1<>"";SATIRSAY(FİLTRE($B$1:$B$2000;($A$1:$A$2000=$A1)*(MUTLAK($B$1:$B$2000-$B1)<4)))>1)

Örnek dosyayı da ekliyorum.

CF_02.xlsx dosyasını indir - download

CF_02.xlsx dosyasını indir, download. Dosya.tc .Dosya Upload. Dosya Paylaş. Dosya Yükle

s2.dosya.tc