Toggle Button ile Boş Satırları Gizle ve Göster Kod Yardımı

[Believing]

Sayın Uzman Arkadaşlar,

Bir çalışma kitabının "VERİ" isimli sayfasının "A3:A1000" aralığındaki bazı satırlarda veri bulunmamaktadır. Bu sayfaya bir Toggle button atayarak, boş satırları gizlemek veya gizli olan satırları görünür hale getirmek istiyorum. Buna göre;
1) Toggle buttona basıldığında "A3:A100" aralığındakı boş satırları gizlenmelidir.
2) Toggle buttonun adı "Boş Satırları Göster" olarak değişmelidir.
3) Tekrar Toggle buttona basıldığında gizlenmiş olan tüm satırlar görünür olmalıdır.
4) Toggle buttonu adı ilk hali olan "Boş Satırları Gizle" olark değişmelidir.
Konu hakkında uzman arkadaşları desteklerini rica ediyorum.

Saygılarımla,
Ömer Ali ÜZÜMCÜ

Örnek Çalışma Linki;
http://s7.dosya.tc/server12/b55d6z/ORNEK_TOGGLE_BUTTON.rar.html

 

[Korhan Ayhan]

Deneyiniz.

Private Sub ToggleButton1_Click()
    With ToggleButton1
        If .Value Then
            Range("A3:A100").SpecialCells(xlCellTypeBlanks).EntireRow.Hidden = True
            .Caption = "Boş Satırları Göster"
        Else
            Range("A3:A100").SpecialCells(xlCellTypeBlanks).EntireRow.Hidden = False
            .Caption = "Boş Satırları Gizle"
        End If
    End With
End Sub

 

[Believing]

Sayın Korhan Ayhan,

Gecenin bu saatinden, konuya bu kadar hızlı cevap vermenizi ifade edecek kelime bulamıyorum. Adeta hızır gibisiniz.
ALLAH sizden ve sevdiklerinizden razı olsun.
Hayırlı geceler.

Saygılarımla
Ömer Ali ÜZÜMCÜ

 

[veyselemre]

Değişiklik olsun,

Private Sub ToggleButton1_Click()
    With ToggleButton1
        Range("A3:A100").SpecialCells(xlCellTypeBlanks).EntireRow.Hidden = .Value
        .Caption = Array("Boş Satırları Göster", "Boş Satırları Gizle")(CInt(.Value) + 1)
    End With
End Sub

 

[Believing]

Sayın Veyselemre,

Konuya gösterdiğiniz ilgi ve alternatif çözümünüz için size de çok teşekkür ederim. Hepinizden ALLAH razı olsun.
Peki A3:A1000 aralığı formül içerir ise, mevcut kodlarda nasıl bir düzenleme yapmalıyım?

Saygılarımla,
Ömer Ali ÜZÜMCÜ

 

[Korhan Ayhan]

Deneyiniz.

Private Sub ToggleButton1_Click()
    Dim Veri As Range, Alan As Range
    
    For Each Veri In Range("A3:A1000")
        If Veri.Value = "" Then
            If Alan Is Nothing Then
                Set Alan = Veri
            Else
                Set Alan = Union(Alan, Veri)
            End If
        End If
    Next
    
    If Not Alan Is Nothing Then
        With ToggleButton1
            If .Value Then
                Alan.EntireRow.Hidden = True
                .Caption = "Boş Satırları Göster"
            Else
                Alan.EntireRow.Hidden = False
                .Caption = "Boş Satırları Gizle"
            End If
        End With
    End If
End Sub

 

[Believing]

Sayın Korhan Ayhan,

Konuya gösterdiğiniz ilgi ve çözümünüz için size ne kadar teşekkür etsem azdır.
ALLAH sizden ve sevdiklerinizden razı olsun.
Hakkınız helal ediniz lütfen.
Kolay gelsin.

Saygılarımla,
Ömer Ali ÜZÜMCÜ

 

[unur]

İyi geceler arkadaşlar;
Bu soruya ilave olarak boş satırları değil de; Örneğin: D43500 satırları arasında HAYIR yazan satırları gizlemek, tekrar basınca tüm satırları görmek istersek, kodlarda nasıl bir revize etmemiz lazım.
Yardımcı olacak arkadaşlara şimdiden Teşekkürler.

 

[Korhan Ayhan]

Deneyiniz.

Private Sub ToggleButton1_Click()
    Dim Veri As Range, Alan As Range
   
    For Each Veri In Range("D4:D3500")
        If Veri.Value = "HAYIR" Then
            If Alan Is Nothing Then
                Set Alan = Veri
            Else
                Set Alan = Union(Alan, Veri)
            End If
        End If
    Next
   
    If Not Alan Is Nothing Then
        With ToggleButton1
            If .Value Then
                Alan.EntireRow.Hidden = True
                .Caption = "HAYIR Yazan Satırları Göster"
            Else
                Alan.EntireRow.Hidden = False
                .Caption = "HAYIR Yazan Satırları Gizle"
            End If
        End With
    End If
End Sub

 

[unur]

Korhan Bey çok teşekkürler.Elinize sağlık