Toplam makrosu geliştirme hk.

[td877]

Arkadaşlar merhaba,

Sub toplam()



[J6:J20].ClearContents
son = Cells(Rows.Count, "J").End(3).Row
With Range("J6:J" & son)
Range("J6:J20").Value = Evaluate("=G6+H6*I6")


End With
End Sub

Şöyle bir makrom var. İlgili bölüme =G6+H6*I6 formulasyonunu yazıyor ama ben rakam olarak yazdırmak istiyorum. Bir örnek verecek olursam.

G6= 10
H6= 5
I6= 5

Sonuçu şekilde yazdırmak istiyorum → =10+5*5 yani formül içinde rakamlar yazsın. Bu yapılabilir mi yardımlarınızı bekliyorum.

Saygılarımla.

 

[Muzaffer Ali]

Merhaba.
aşağıdaki kod ile yapabilirsiniz.

Sub toplam()
    Dim Bak As Range
    For Each Bak In Range("J6:J20")
        Bak.Value = "'=" & Range("G" & Bak.Row) & "+" & Range("H" & Bak.Row) & "*" & Range("I" & Bak.Row)
    Next
End Sub

 

[td877]

Merhaba sayın dalgalıkur,

Bir kaç modifikasyon yapabilir miyiz, hücre başına ' ekliyor dolayısıyla formülasyon oluşmuyor. Birde çektiği hücrelerde (herhangi birinde) sadece rakam varsa bu işlemi gerçekleştirebilir mi? Rakam yoksa boş bıraksın gibi.

 

[Muzaffer Ali]

Aşağıdaki kodu deneyin.

Sub toplam()
    Dim Bak As Range
    For Each Bak In Range("J6:J20")
        If IsNumeric(Range("G" & Bak.Row)) And IsNumeric(Range("H" & Bak.Row)) And IsNumeric(Range("I" & Bak.Row)) And _
            Not IsEmpty(Range("G" & Bak.Row)) And Not IsEmpty(Range("H" & Bak.Row)) And Not IsEmpty(Range("I" & Bak.Row)) Then
            Bak.Value = "=" & Range("G" & Bak.Row) & "+" & Range("H" & Bak.Row) & "*" & Range("I" & Bak.Row)
        Else
            Bak.Value = ""
        End If
    Next
End Sub

 

[td877]

Şöyle bir problem oluyor bunu formulasyon olarak yazmadığı için başına ' işareti ekliyor. Hani =5+5+5 ENTER dersin formüle girer ya bu şekilde yapabilir miyiz?

 

[Muzaffer Ali]

En son yazdığım kodlar formülün başına "'" işareti eklemiyor.
Hücreye =5+5+5 yazıyor. Bu yazılan değer bir formül olduğu için sanki Enter'e basılmış gibi hemen hesaplama yapıyor hücrede 15 değerini gösteriyor.

Siz tam olarak ne istiyorsunuz ben anlayamadım.

 

[td877]

Tam olarak sizin yazdığınız şeyi istiyorum ama yapmıyor neden anlamadım hata veriyor. Run time error 1004 diyor. Debug diyince

Bak.Value = "=" & Range("G" & Bak.Row) & "+" & Range("H" & Bak.Row) & "*" & Range("I" & Bak.Row)

satırını sarı yakıyor.

 

[Muzaffer Ali]

Dosyanız ekte

 

[td877]

Oldu şimdi teşekkür ederim. Metin biçimlendirmesi var diye hücrelerde sorun oluyormuş hocam. Kolaylıklar dilerim.

 

[td877]

İlave birşey sorabilir miyim, ilgili rakam ondalık sayı olursa yine hata verdiğini farkettim macronun (yani 5,05 gibi) modifikasyon yapılabilir mi?

 

[Muzaffer Ali]

Formül içindeki virgülü ayraç olarak gördüğünden kaynaklanıyor.

Aşağıdaki kodları kullanın.

Private Sub btmTopla_Click()
    Dim Bak As Range
    Dim G As String, H  As String, I  As String
    For Each Bak In Range("J6:J20")
        If IsNumeric(Range("G" & Bak.Row)) And IsNumeric(Range("H" & Bak.Row)) And IsNumeric(Range("I" & Bak.Row)) And _
            Not IsEmpty(Range("G" & Bak.Row)) And Not IsEmpty(Range("H" & Bak.Row)) And Not IsEmpty(Range("I" & Bak.Row)) Then
            G = Replace(Range("G" & Bak.Row), ",", ".")
            H = Replace(Range("H" & Bak.Row), ",", ".")
            I = Replace(Range("I" & Bak.Row), ",", ".")
            Bak.Formula = "=" & G & "+" & H & "*" & I
        Else
            Bak.Value = ""
        End If
    Next
End Sub

 

[td877]

Çok teşekkür ederim tıkır tıkır çalışıyor şuan Kolay gelsin.

 

[td877]

Tekrar merhaba sayın dalgalikur

Şöyle bir geliştirme yapılabilir mi çektiği hücrelerin içinde de formulasyon olsa. Varsa hücre içeriğini de string olarak alsa. Örnekte anlatmaya çalıştım.

=13+25+20+3*3 gibi.

 

[Muzaffer Ali]

Merhaba.

Aşağıdaki kodlar ile olur.

Private Sub btmTopla_Click()
    Dim Bak As Range
    Dim G As String, H  As String, I  As String
    For Each Bak In Range("J6:J20")
        If IsNumeric(Range("G" & Bak.Row)) And IsNumeric(Range("H" & Bak.Row)) And IsNumeric(Range("I" & Bak.Row)) And _
            Not IsEmpty(Range("G" & Bak.Row)) And Not IsEmpty(Range("H" & Bak.Row)) And Not IsEmpty(Range("I" & Bak.Row)) Then
            G = WorksheetFunction.Substitute(Range("G" & Bak.Row).Formula, "=", "")
            H = WorksheetFunction.Substitute(Range("H" & Bak.Row).Formula, "=", "")
            I = WorksheetFunction.Substitute(Range("I" & Bak.Row).Formula, "=", "")
            Bak.Formula = "=" & "(" & G & ")" & "+" & "(" & H & ")" & "*" & "(" & I & ")"
        Else
            Bak.Value = ""
        End If
    Next
End Sub

 

[td877]

Hocam çok teşekkür ederim.