user form sayfada ara ve kaydet

[netvolxxx]

merhaba şöyle bir excel çalışma kitabım var

sayfa1
a1 hücresinde verilerim var örnek:
ahmet
mehmet
metin
emin
emine gibi veriler....
sayfa 2 buton ile form açılıyor textbox kısmına yazdığım sayfa 1 deki a1 hücresinde yazılı olan verilerden tam eşleşme olmadan ( emi yazdığımda bana emin ve emine) olarak getircek formda listelemesini istiyorum.
listelenen içinde seçip sayfa 2 de hangi satır üzerinde isem oraya aktarsın bunu kod olarak nasıl yapabilirim.

 

[AdemCan]

Merhaba,
Örnek bir çalışma hazırladım.

Gerekli nesneler
1- Userform
2- Textbox
3- CommandButton
4- Listbox

Spoyler: Userform Görünüm

Aşağıdaki kodları userforma ekleyip, arama işlemi sonucu listeye gelen sonuçlardan istediğiniz kaydın üzerine çift tıklayarak sayfaya ekleyebilirsiniz.
Not: Sayfa2 A sütununa kayıt eder.

Public s1 As Worksheet, s2 As Worksheet, son As Long, i As Long
Private Sub CommandButton1_Click()
Set s1 = Sayfa1
son = s1.Range("A" & Rows.Count).End(xlUp).Row

If TextBox1.Value = "" Then
    ListBox1.Clear
    Exit Sub
End If

For i = 1 To son
    If LCase(s1.Cells(i, 1)) Like "*" & LCase(TextBox1.Value) & "*" Then
        ListBox1.AddItem s1.Cells(i, 1)
    End If
Next i
End Sub

Private Sub CommandButton2_Click()
ListBox1.Clear
TextBox1 = ""
End Sub

Private Sub ListBox1_DblClick(ByVal Cancel As MSForms.ReturnBoolean)
Set s2 = Sayfa2
s2.Range("A" & ActiveCell.Row) = ListBox1.List(ListBox1.ListIndex)
End Sub

 

[netvolxxx]

adem bey evet denedim çalışıyor istediğim buydu teşekürr ederim....

 

[AdemCan]

Rica ederim.

 

[netvolxxx]

şöyle bir şey yapsak peki hocam sayfa 2 hangi sütun da isem ona nasıl ekleriz örnek b sütünde isem b ye ekleme bunu nasıl yaparım denedim de iki sütuna birden ekledi... excel a sütunda isem a ya eklicem b sütunda isem b ye sadece iki sütun için

 

[AdemCan]

s2.Range("A" & ActiveCell.Row) = ListBox1.List(ListBox1.ListIndex)

satırını aşağıdaki kod ile değiştiriniz.

s2.Cells(ActiveCell.Row, ActiveCell.Column) = ListBox1.List(ListBox1.ListIndex)

 

[netvolxxx]

süper hocam thanks...

 

[AdemCan]

Rica ederim, iyi çalışmalar.