Çözüldü Uzantı sayısına göre dosya boyutunu hesaplatmak

[k0081]

Aktif klasör ve alt klasörlerden belirlediğimiz dosyaların toplam boyutunu MB ( Megabayt ) cinsinde bir değişkene nasıl alabiliriz ?


yardımcı arkadaşa şimdiden Teşekkür ederim.

 

[Haluk]

Aşağıdaki kod; bulunduğu klasör ve tüm alt klasörlerdeki "PDF" uzantılı dosyaların toplam adedini ve boyutunu verir.

'   Haluk
'   30/12/2018
'
Dim Counter As Long, sumSize As Double
'
Sub Test()
    Dim myFolder As String
 
    myFolder = ThisWorkbook.Path
    Call GetFiles(myFolder, True)
 
    MsgBox "PDF dosya sayisi= " & Counter & vbCrLf & vbCrLf & "Toplam PDF boyutu=" & Format((sumSize / 1024) / 1024, "0.00 MB")
 
    Counter = Empty
    sumSize = Empty
End Sub
'
Sub GetFiles(SourceFolder As String, IncludeSubFolders As Boolean)
    Dim FSO As Object, strFolder As Object
    Dim SubFolder As Object, strFile As Object
 
    Set FSO = CreateObject("Scripting.FileSystemObject")
    Set strFolder = FSO.GetFolder(SourceFolder)
 
    For Each strFile In strFolder.Files
        If LCase(FSO.GetExtensionName(strFile.Name)) = "pdf" Then
            Counter = Counter + 1
            sumSize = sumSize + strFile.Size
        End If
    Next
 
    If IncludeSubFolders = True Then
        For Each strFolder In strFolder.SubFolders
            GetFiles strFolder.Path, True
        Next
    End If
 
    Set strFolder = Nothing
    Set FSO = Nothing
End Sub

.

 

[k0081]

Haluk


Hocam çok Teşekkür ediyorum Tamamdır... elinize - yüreğinize sağlık.

 

[askm]

Haluk Bey konu ile alakalı ben de bir soru sorabilir miyim. Sadece konuya baktığım ve bazen gerek olabildiği için meraktan soruyorum.
Ana dizin ve altında 10-15 klasör olsun. Bu alt klasörlerin boyutlarını listeleme imkanı olur mu?

 

[Zeki Gürsoy]

Ana dizin ve altında 10-15 klasör olsun. Bu alt klasörlerin boyutlarını listeleme imkanı olur mu?

Alt dizinlerin gerekli olmadığını varsayarak;

for each fld in fso.getfolder("c:\testfolder").subfolders
    debug.print fld.size
next

 

[askm]

Zeki bey teşekkür ederim.

 

[k0081]

Haluk

Hocam merhaba.;

Bu kodlara Progresbar ı ekleme şansımız olabilirmi ? klasör çok olduğunda , süre uzuyor malum...

Teşekkürler.

 

[Haluk]

Haluk

Hocam merhaba.;

Bu kodlara Progresbar ı ekleme şansımız olabilirmi ? klasör çok olduğunda , süre uzuyor malum...

Teşekkürler.

Merhaba;

Kodlara ProgressBar nesnesi veya onun işini görecek şekilde standart nesnelerle ProgressBar'ın simulasyonu yapılabilir.

________________________
|                       |
||||||||| % 58          |
|_______________________|

Ancak; yukarıda örnek olarak verdiğim ASCII -şeklinde görüldüğü gibi, söz konusu %58'i hesaplayıp da ProgressBar nesnesine yazdırabilmek için ilk önce tamamının önceden hesaplanmış olması gerekir ki; bu yüzde değeri hesaplanabilsin. Sizin probleminizde zaten alt klasör veya dosya sayısı bilinmediği için recursive tarzında (kendi kendini tetikleyen) bir kod hazırlamıştık.

Diğer yandan; siz klasörlerin fazlalığından dolayı kodun uzun sürdüğünden bahsediyorsunuz. Şunu unutmamanız gerekir ki; kodlara ProgressBar nesnesi ilave edildiği zaman, kodların çalışma süresi gerekli "%" hesaplaması nedeniyle daha da uzayacak ve ProgressBar'ın ekran tazelemesi gereksinimi nedeniyle sizin performansınızı iyice düşürecektir.

.

 

[k0081]

Haluk

________________________
|                       |
||||||||| % 58          |
|_______________________|

Ancak; yukarıda örnek olarak verdiğim ASCI -şeklinde görüldüğü gibi, söz konusu %58'i hesaplayıp da ProgressBar nesnesine yazdırabilmek için ilk önce tamamının önceden hesaplanmış olması gerekir ki; bu yüzde değeri hesaplanabilsin. Sizin problemizde zaten alt klasör veya dosya sayısı bilinmediği için recursive tarzında bir kod hazırlamıştık.

Hocam recursive tarzındaki bu uygulamaya simulasyon ekleyemeyiz mi, doğrumu ? yukarıdaki ASCI deki gibi bir uygulama işi görecektir.

||||||||| % 58 <- bu da yeterli olur. Bu zamanı nasıl hesaplatabilirz hocam

 

[Haluk]

Sonu belli olmayan bu tür hesaplarda en kötü ihtimalle kodu 2 defa çalıştırırsınız. 1nci'sinde gerekli "toplam" miktarı bulursunuz, 2nci defa çalıştırıp, bu kez de ProgressBar'da % hesaplama işini yaparsınız. Bu işleri yaparken de çalışma süresi iyice artar tabii....

ProgressBar örnekleri de zaten forumda var.

İyi seneler...

.

 

[k0081]

Anladım. Teşekkür ediyorum Haluk bey.

İyi seneler...