Soru veri olmayan satırları gizleme

[sirkülasyon]

Private Sub ToggleButton1_Click()
    Dim Veri As Range, Alan As Range
    For Each Veri In Range("G5:G99")
        If Veri.Value = "" Then
            If Alan Is Nothing Then
                Set Alan = Veri
            Else
                Set Alan = Union(Alan, Veri)
            End If
        End If
    Next
    If Not Alan Is Nothing Then
        With ToggleButton1
            If .Value Then
                Alan.EntireRow.Hidden = True
                .Caption = "Boş Satırları Göster"
            Else
                Alan.EntireRow.Hidden = False
                .Caption = "Boş Satırları Gizle"
            End If
        End With
    End If 
End Sub

yukarıda yer alan kod ile veri olmayan satırları gizliyorum. Ancak bir değişiklik yapmak istiyorum.
G5 : G99 arasında veri olan satırlar görünsün diğer tüm satırlar tamamen gizlensin. Bunun için yardımcı olabilir misiniz?

 

[veyselemre]

Private Sub ToggleButton1_Click()
    Dim Veri As Range, Alan As Range
    Range("1:4").EntireRow.Hidden = True
    Range("100:" & Rows.Count).EntireRow.Hidden = True
    For Each Veri In Range("G5:G99")
        If Veri.Value = "" Then
            If Alan Is Nothing Then
                Set Alan = Veri
            Else
                Set Alan = Union(Alan, Veri)
            End If
        End If
    Next
    If Not Alan Is Nothing Then
        With ToggleButton1
            If .Value Then
                Alan.EntireRow.Hidden = True
                .Caption = "Boş Satırları Göster"
            Else
                Alan.EntireRow.Hidden = False
                .Caption = "Boş Satırları Gizle"
            End If
        End With
    End If
End Sub

 

[Muzaffer Ali]

Merhaba.

Aşağıdaki kodları deneyin.(Alternatif)

Private Sub ToggleButton1_Click()
    Dim Veri As Range
    With ToggleButton1
        If .Value Then
            Cells.EntireRow.Hidden = True
            For Each Veri In Range("G5:G99")
                If Veri.Value <> "" Then
                    Veri.EntireRow.Hidden = False
                End If
            Next
            Range("G5:G99").End(xlUp).Select
            .Caption = "Tüm Satırları Göster"
        Else
            Cells.EntireRow.Hidden = False
            .Caption = "Boş Satırları Gizle"
        End If
    End With
End Sub

 

[sirkülasyon]

veyselemre ve Muzaffer Ali ustalarıma teşekkür ederim. Sağ olun
Ellerinize sağlık.