Word Belgeleri açmadan içeriği düzenleme

[Erhan Köseoğlu]

Elimde 1000 den fazla word belgesi var, bu belgelerdeki bilgileri ve özellikle üst bilgide yer alan logoyu değiştirmek istiyorum. Bunu belgeleri açmadan yapmak istiyorum. Bunu nasıl düzenleriz?

 

[necati]

Merhaba, örnek bir makro paylaşıyorum. Boş bir belgede bu makroyu çalıştırabilirsiniz. Belgelerinizin klasörünü yol = "D:\deneme" satırını ve logonun bulunduğu konum olan imajyolu = "C:\Belgelerim\Pictures\LOGO.PNG" satırını kendinize göre düzenleyiniz.

Sub Logodegisimi()
Dim yol As String, dosya As String
Dim belge As Document
Dim rng As Range, shp, yenishp
Dim imajyolu As String

imajyolu = "C:\Belgelerim\Pictures\LOGO.PNG"
yol = "D:\deneme"
Dosya = Dir(yol & "\*docx")
Application.ScreenUpdating = False
Do While Dosya <> ""
Set belge = Application.Documents.Open(yol & "\" & Dosya, Visible:=False)

With belge.Sections(1)
    If .Headers(wdHeaderFooterPrimary).Exists Then
        Set rng = .Headers(wdHeaderFooterPrimary).Range
        If rng.InlineShapes.Count > 0 Then
            Set shp = rng.InlineShapes(1)
            If shp.Type = wdInlineShapePicture Then
                Set yenishp = rng.InlineShapes.AddPicture(fileName:=imajyolu, _
                    LinkToFile:=False, SaveWithDocument:=True)
                yenishp.Width = shp.Width
                yenishp.Height = shp.Height
                shp.Delete
            End If
        belge.Close True
        Else
        belge.Close False
        End If
    End If
End With
Dosya = Dir
Loop
Application.ScreenUpdating = True
MsgBox "İşlem tamam", vbInformation
End Sub